Excel: SI.CONDITIONS > plusieurs SI en une seule fonction

La fonction Excel SI.CONDITIONS peut exécuter plusieurs tests et renvoyer une valeur correspondant au premier résultat VRAI. Utilisez la fonction SI.CONDITIONS pour évaluer plusieurs conditions en même temps sans devoir passer par plusieurs fonctions SI imbriquées. SI.CONDITIONS permet d'avoir des formules plus courtes et plus faciles à lire.
Tout comme SI.MULTIPLE, il s'agit d'une fonction Excel assez récente qui était introduite dans Excel 2019.

La syntaxe de la fonction SI.CONDITIONS dans Excel

La fonction Excel SI.CONDITIONS a une syntaxe très simple bien qu'il soit possible d'utiliser une grande quantité d'arguments.

=SI.CONDITIONS(Test_logique1;Valeur_si_vrai1;Test_logique2;Valeur_si_vrai2;…;Test_logique127;Valeur_si_vrai127)

 

Les paramètres de la fonction SI.CONDITIONS

Ceci sont les noms des arguments tels que vous les trouverez dans Excel. J'aurais probablement choisi des termes plus explicites mais soyons cohérents avec Microsoft…

  • Test_logique1 : Une valeur ou l'expression dont le résultat peut être VRAI. Il peut s'agir de l'adresse d'une cellule (dont la valeur sera utilisée), d'une comparaison logique ou d'une formule (dont le résultat sera utilisé). Il s'agit du premier test qui sera utilisé. Ce paramètre est obligatoire.
  • Valeur_si_vrai1 : La valeur renvoyée si le résultat du Test_logique1 est VRAI. Il peut également s'agir d'une valeur, d'une référence dont la valeur sera utilisée (donc par exemple l'adresse d'une cellule) ou encore une formule dont le résultat sera affiché… Ce paramètre est obligatoire.
  • ...
  • Test_logique127 : Le 127ème et dernier test logique qui peut être utilisé. Tous les paramètres après les deux premiers sont facultatifs.
  • Valeur_si_vrai127 : La valeur renvoyé si le 127ème (et donc l'ultime) test est considéré comme VRAI.

Plusieurs exemples d'utilisation se trouvent dans les sections qui suivent pour une compréhension plus facile…

Excel: SI.CONDITIONS - paramètre 'test_logique'
Excel: SI.CONDITIONS – paramètre 'test_logique'

 

Excel: SI.CONDITIONS - paramètre 'valeur_si_vrai'
Excel: SI.CONDITIONS – paramètre 'valeur_si_vrai'

Pour information:

  • l'équivalent anglophone de cette fonction est la fonction IFS
  • SI.CONDITIONS est disponible dans Excel 2019, Excel 2021 et Excel 365

La fonction SI.CONDITIONS en pratique

Les conditions sont fournies à la fonction SI.CONDITIONS sous forme de paires test/valeur dont SI.CONDITIONS peut gérer jusqu'à 127. Chaque test représente un test logique qui renvoie VRAI ou FAUX, et la valeur qui suit sera renvoyée lorsque le test renvoie VRAI. Dans le cas où plusieurs conditions renvoient VRAI, la valeur correspondant au premier résultat VRAI est renvoyée. Pour cette raison, il est important de considérer l'ordre dans lequel les conditions apparaissent.

Voici quelques points d'attention lors de l'utilisation de SI.CONDITIONS :

  • La fonction SI.CONDITIONS n'a pas de valeur par défaut intégrée à utiliser lorsque toutes les conditions sont fausses.
  • Pour fournir une valeur par défaut, entrez VRAI comme test final et une valeur à renvoyer lorsqu'aucune autre condition n'est remplie.
  • Tous les tests logiques doivent renvoyer VRAI ou FAUX. Tout autre résultat obligera SI.CONDITIONS à renvoyer l'erreur #VALEUR!.
  • Si aucun test logique ne renvoie VRAI, SI.CONDITIONS renverra l'erreur #N/A.

Dans l'exemple suivant, la fonction prend le résultat d'un test dans la cellule B2 et renvoie une valeur qui y correspond:

=SI.CONDITIONS(B2<20;"Insuffisant";B2<40;"Suffisant";B2>40;"Excellent")

Vous pouvez constater que la formule est assez bien lisible. Notez le fait que l'adresse de la cellule (B2) est répété dans chaque test. Mais la formule finale a une meilleure lisibilité que des SI imbriqués comme suit:

=SI(B2<20;"Insuffisant";SI(B2<40;"Suffisant";SI(B2>40;"Excellent")))

… et là, nous n'en sommes qu'à 3 conditions possibles. Imaginez si vous en avez 7 ou 10…

Les tests logiques que vous utilisez peuvent contenir des chaînes de caractères ("client", "fournisseur",…), des nombres (1000, 12, 25,5,…) ou encore des adresses de cellules (D2, $E$53,…) mais ils doivent avoir comme résultat possible VRAI ou FAUX.

Une meilleure lisibilité

Pour une meilleure lisibilité dans la "barre de formule Excel", vous pouvez écrire la fonction sur plusieurs lignes avec Alt + Entrée. Cela vous donnera alors ceci:

Excel: SI.CONDITIONS sur plusieurs lignes
Excel: SI.CONDITIONS sur plusieurs lignes

 

Exemples d'utilisation de la fonction SI.CONDITIONS

Maintenant que vous avez vu les concepts de base, voici des exemple pratiques d'utilisation de cette fonction:

Exemple 1) Calcul de trimestre d'une date:

Dans cette exemple, on attribue une des valeurs ( 1 T, 2 T, 3 T ou 4 T) selon la date qui se trouve dans la cellule E2. Notez que nous utilisons une fonction dans le test logique ( MOIS ). Remarquez aussi l'ordre des tests logiques qui tient compte du fait que SI.CONDITIONS s'arrête au premier résultat positif…

=SI.CONDITIONS(MOIS(E2)<=3;"1 T";MOIS(E2)<=6;"2 T";MOIS(E2)<=9;"3 T";MOIS(E2)<=13;"4 T")

Exemple 2) Utilisation des références / formules en tant que valeur à retourner:

Vous n'êtes pas obligés de retourner uniquement des valeurs "fixes" comme résultat. Vous pouvez retourner également le contenu des cellules ou même le résultat de divers calculs.

=SI.CONDITIONS(A2<100;B2*D2;A2=100;B2*E2;A2>100;I2*J2)

Exemple 3) Utilisation des différents données dans les tests logiques:

Cette fonction, contrairement au SI.MULTIPLE vous donne la possibilité d'utiliser des données différents dans chaque test logique. Ainsi

=SI.CONDITIONS(A2=100;"OK";B2<100;"OK aussi";C2<1000;"Pas OK")

Exemple 4) La valeur à renvoyer si tous les test sont FAUX:

Et voici la syntaxe qui vous permet d'obtenir une "valeur par défaut" – c'est à dire la valeur qui sera renvoyée par la formule au cas où tous les test logiques sont FAUX. Dans cet exemple, si le "code produit" qui se trouve dans la cellule A1 est 1, il s'agir de fruits, s'il est 2 ou 3, il s'agit de légumes et enfin si le code est 4 ou 5, il s'agit des produits laitiers. Aucun autre code produit n'est prévu. Si un autre code est utilisé, il faut avertir qu'il s'agit d'une donnée incorrecte.

=SI.CONDITIONS(A1=1;"Fruits";A1<=3;"Légumes";A1<=5;"Produits laitiers";VRAI;"Catégorie incorrecte")

Explication: la formule contient 3 paires test/réponse "classiques". S'ils sont tous faux, Excel passera à la quatrième paire. Le test logique du VRAI est, logiquement 🙂 ) toujours égal à VRAI. C'est donc la 4ème réponse qui sera renvoyée. Si vous n'utilisez pas cette 4ème paire, Excel renverra comme résultat de la formule l'erreur #N/A !

Vous voici donc familiarisés avec cette fonction bien pratique qui peut vous faciliter la vie notamment en supprimant le besoin d'utiliser les formules SI imbriquées. Son utilisation est assez simple et directe. Donc si vous disposez d'une des dernières versions d'Excel, n'hésitez pas à vous en servir!

Quelles sont les différences entre SI.CONDITIONS et SI.MULTIPLE ?

Comme la fonction SI.MULTIPLE, la fonction SI.CONDITIONS vous permet de tester plusieurs conditions dans une seule formule autonome. Ces deux fonctions facilitent l'écriture (et la lecture) d'une formule avec de nombreuses conditions.

Un avantage de SI.MULTIPLE par rapport à SI.CONDITIONS est que l'expression n'apparaît qu'une seule fois dans la fonction et n'a pas besoin d'être répétée. De plus, SI.MULTIPLE peut accepter une valeur par défaut.

Cependant, SI.MULTIPLE est limité à une correspondance exacte. Il n'est pas possible d'utiliser des opérateurs tels que supérieur à (>) ou inférieur à (<) avec la syntaxe standard. En revanche, la fonction SI.CONDITIONS nécessite des expressions pour chaque condition, vous pouvez donc utiliser des opérateurs logiques selon vos besoins.

Pour aller plus loin en Excel…

Et si vous voulez explorer un peu plus les possibilités que vous offre Excel, voici quelques articles qui pourraient vous intéresser…

 

Laissez un commentaire

Votre adresse e-mail ne sera pas publiée.