La fonction Excel SI est l'une des fonctions Excel les plus utilisées au quotidien. Elle permet d’évaluer une valeur (habituellement la valeur d’une cellule) selon une condition et de renvoyer une valeur différente selon si la condition est remplie ou pas.
Sommaire
- La syntaxe de base de la fonction Excel SI
- Exemple d'utilisation de la fonction SI dans une formule Excel
- Fonctions SI imbriquées – Multiples Conditions dans Excel
- Formule Excel SI avec deux ou plusieurs conditions
- Autres utilisations de la fonction SI et les fonctions apparentées
- Pour aller plus loin en Excel…
La syntaxe de base de la fonction Excel SI
La syntaxe est relativement simple et se compose de trois parties:
- Condition – la condition compare deux valeurs (valeurs en dur, valeurs de cellule ou résultats de fonction) l’une par rapport à l’autre grâce à un des opérateurs logiques de Excel:
- est égal à (
=) - est différent de (
<>) - est supérieur à (
>) - est supérieur ou égal à (
>=) - est inférieur à (
<) - est inférieur ou égal à (
<=)
- est égal à (
- Valeur si Condition est remplie – c'est la valeur (ou formule) que la fonction SI va renvoyer au cas où la condition est vraie (cet argument est facultatif)
- Valeur si Condition n’est pas remplie – valeur (ou formule) renvoyé par la fonction SI dans le cas où la condition n'est pas remplie (cet argument est facultatif)
Les valeurs renvoyés comme réponse peuvent contenir un texte (comme par exemple "Oui" ou "Non"), un chiffre, le contenu d’une cellule spécifique ou même une autre formule (qui peut, par exemple être une autre fonction SI – voir la section "Fonctions SI imbriquées" plus loin). Voici quelques exemples:
=SI(A3>6; "Oui"; "Non")=SI(A3>6; A3; 0)=SI(A3>6; B3*C3; B3*D3-2)
La valeur que l’on veut "tester" provient habituellement d’une cellule mais il peut s’agir de n’importe quelle valeur.
Exemple d'utilisation de la fonction SI dans une formule Excel
Passons maintenant à un exemple pratique de la vie quotidienne.
Nous pouvons tester, par exemple, si le jour d’aujourd’hui est un lundi et, selon le résultat, renvoyer une réponse approprié. Cet exemple exprimé en tant que formule Excel nous donne ceci:
=SI(JOURSEM(AUJOURDHUI();2)=1;"7 rapports à exécuter";"2 rapports à exécuter")
Vous pouvez constater que l'on teste le résultat d’une formule et non une valeur de cellule.
Maintenant que l'on s'est familiarisé avec la syntaxe de la fonction SI, on peut regarder de plus près son utilisation pratique.
Comme les deux arguments ("si vrai" et "si faux") sont facultatifs, il est possible d'écrire une formule en n'utilisant qu'un d'eux. Vous pouvez donc utiliser par exemple les formules SI suivantes:
=SI(A3<5;"test")– si la valeur de la cellule A3 est plus petite que 5, le résultat sera "test", sinon le résultat sera vide.=SI(A3<5;;"négatif")– la fonction renvoie un résultat (mot "négatif") uniquement dans le cas où la cellule A3 a une valeur supérieure ou égale à 5. Notez que le résultat souhaité (mot "négatif") doit se trouver à sa place de 3ème argument (c'est pour cela qu'il y a deux point-virgules d'affilé)…
Fonctions SI imbriquées – Multiples Conditions dans Excel
Vous avez probablement déjà rencontré la situation qui exigeait de "mettre plusieurs fonctions SI les unes dans les autres". Il s'agit même de d'une situation tout à fait courante. Voici quelques informations et astuces pour vous permettre de gérer une telle situation (formule) de manière efficace et efficiente.
1. Utilisation des "paliers" dans les formules SI Excel
Pour faire simple, commençons par un exemple pratique:
Vous voulez grouper les problèmes d'après leur score pour pouvoir leur attribuer une priorité. Les groupes sont les suivants:
- score inférieur à 5 = "priorité faible"
- score entre 5 et 10 = "priorité moyenne"
- score entre 10 et 15 = "priorité haute"
- et score supérieur à 15 = "priorité absolue"
Si on suit ce raisonnement à la lettre, on va se retrouver avec une formule SI qui ressemblera à celle-ci:
=SI(A1<5;"priorité faible";SI(ET(A1>=5;A1<10)=VRAI;"priorité moyenne";SI(ET(A1>=10;A1<15)=VRAI;"priorité haute";SI(ET(A1>=15;A1<=20)=VRAI;"priorité absolue";""))))
Heureusement, la logique nous permettra de simplifier cette formule SI très peu lisible.
La formule SI suivante donnera exactement le même résultat que la précédente. Tout en étant plus simple et plus rapide:
=SI(A1<5;"priorité faible";SI(A1<10;"priorité moyenne";SI(A1<15;"priorité haute";SI(A1<=20;"priorité absolue";""))))
Attention: quand vous allez déterminer vos paliers numériques, n'oubliez pas d'inclure/exclure les valeurs extrêmes des paliers pour que ces valeurs se retrouvent dans le palier correct (donc attention à la différence entre < et <= ainsi que entre > et >=). Dans l'exemple qui suit, la valeur "5" se retrouvera dans les paliers différents (dans le premier cas dans le premier palier, dans l'autre cas dans le deuxième palier):
=SI(A1<=5;"priorité faible";SI(A1<=10;"priorité moyenne";SI(A1<=15;"priorité haute";SI(A1<=20;"priorité absolue";""))))=SI(A1<5;"priorité faible";SI(A1<10;"priorité moyenne";SI(A1<15;"priorité haute";SI(A1<=20;"priorité absolue";""))))
2. Ordre des Conditions SI selon la probabilité
L'utilisation des fonctions SI est relativement gourmande en ce qui concerne les ressources de votre ordinateur. Si vous utilisez un grande nombre de ce type de formules, ce qui suit pourrait vous intéresser.
Dans le cas des fonctions SI imbriquées, Excel évalue la première condition et si elle n'est pas remplie, il continue avec la deuxième, puis la troisième et ainsi de suite. Excel arrête le calcul seulement au moment ou une condition est remplie et un résultat peut être affiché. La règle qui en découle est la suivante:
Si vous le pouvez, veuillez à ce que la condition "VRAI" ait lieu le plus tôt possible. Autrement dit, commencez d'abord avec les conditions qui ont le plus de chances à être vraies. Ainsi, vous limitez le temps qu'Excel doit passer à calculer le résultat de la formule.
Un conseil donc: commencez avez une condition générale et gardez les exceptions pour la fin de votre formule SI imbriquée.
Exemple pratique: Si vous avez un commerce local à Lyon et vous voulez déterminer la nationalité de vos clients, vous avez tout intérêt à ne pas utiliser cette formule-ci:
=SI(PrenomClient="John";"Américain";SI(PrenomClient="Ivan";"Russe";SI(PrenomClient="Luigi";"Italien";SI(PrenomClient="Jean";"Français";""))))
mais à utiliser celle-ci:
=SI(PrenomClient="Jean";"Français";SI(PrenomClient="Luigi";"Italien";SI(PrenomClient="John";"Américain";SI(PrenomClient="Ivan";"Russe";""))))
La seconde formule sera nettement plus rapide que la première (en assumant que la plupart de clients sont Français)…
3. Limitation du nombre des fonctions SI imbriqués dans une formule Excel
Vous l'avez peut-être constaté par vous-mêmes: les développeurs de Microsoft ont limité le nombre des fonctions SI que vous pouvez imbriquer. Jusqu'à la version Excel 2003, ce maximum était de 7. À partir de Excel 2007, cette limite est augmentée à 64. Mais soyons réalistes: ce chiffre est purement théorique car en pratique une telle formule serait inutilisable! Même si on considère uniquement la limite de 7 fonctions (pour garantir la compatibilité avec Excel 2003), ce chiffre est, à mon avis, plus suffisant pour la grande majorité d'utilisateurs d'Excel.
Si vous voulez vraiment utiliser plus de 7 imbrication de la fonction SI, vous trouverez le mode d'emploi ici. Cependant, je le déconseille vivement pour deux raisons:
- une telle formule SI aura un impact considérable sur la performance (surtout si la formule est utilisée x-fois)
- cette fonction sera presque illisible et très difficilement modifiable. Il y a de fortes chances que vous allez vous perdre dans toutes ces parenthèses…
La bonne nouvelle est qu'il existe des alternatives. Vous les trouverez un peu plus loin sur cette page.
4. Astuces pour l'utilisation des formules avec des fonctions SI imbriquées
Heureusement, il existent certaines astuces pour rendre le travail avec des fonctions SI imbriquées plus facile. En voici deux:
4.1. Utilisation du retour à la ligne dans la "Barre de formule"
Normalement, une formule s'affiche en "sans interruption" dans la "Barre de formule" vous pouvez donc y voir ce type de formule:
=SI(C2<2;"très bas";SI(C2<5;"bas";SI(C2<9;"moyenne inférieure";SI(C2<12;"moyenne supérieure";SI(C2<15;"élevé";"très élevé")))))
Ce qui donne donc ceci:
Comme vous pouvez le constater, une telle formule SI est difficilement lisible.
Mais on peut profiter du fait que les formules dans Excel sont insensibles aux espaces et aux retours à la ligne entre différents arguments. En plaçant des retours à la ligne aux bons endroits, nous pouvons rendre la formule beaucoup plus lisible. Un retour à la ligne dans Excel s'effectue en appuyant sur les touches Alt et Entrée.
Pour exactement la même formule, on peut donc avoir ceci dans la "Barre de formule":
=SI(C2<2;"très bas";
SI(C2<5;"bas";
SI(C2<9;"moyenne inférieure";
SI(C2<12;"moyenne supérieure";
SI(C2<15;"élevé";"très élevé")))))
N'est-ce pas bien plus lisible et plus simple à modifier?
4.2. Couleurs de parenthèses pour retrouver plus facilement les paires
Le problème que tout le monde a déjà probablement rencontré dans Excel est l'utilisation des parenthèses dans des formules Excel complexes. Ce n'est pas toujours facile d'avoir le bon nombre de parenthèses aux bons endroits. Et dans les formules avec des fonctions SI imbriquées, ce problème a lieu régulièrement.
Heureusement, il y a une aide pour cela. Quand vous cliquez dans la "Barre de formule" qui contient votre formule, Excel va vous afficher, avec des couleurs diverses, les cellules utilisées dans votre formule. Mais pas seulement! Il affiche également les paires des parenthèses correspondantes avec les couleurs différentes pour chaque paire. Il est donc plus facile de s'y retrouver. Et ceci est valable également pour d'autres formules complexes en Excel.
5. Alternatives aux formules SI imbriquées
Si vous cherchez une alternative pour éviter la lourdeur des fonctions SI imbriquées, je vous propose les deux suivantes.
- Excel 2019 nous apporte, parmi ses nouveautés, les fonctions SI.CONDITIONS et SI.MULTIPLE qui peuvent remplacer la structure des fonctions SI imbriquées. Ces fonctions vous permettent de lister des conditions et des résultats à afficher au cas où la condition est remplie. Un exemple: Si on utilisait la fonction SI.CONDITIONS à la place de la fonction SI dans notre exemple de la nationalité des clients d'un commerce local, on obtiendrait la formule:
=SI.CONDITIONS(PrenomClient="Jean";"Français";PrenomClient="Luigi";"Italien";PrenomClient="John";"Américain";PrenomClient="Ivan";"Russe";"")La différence n'est pas énorme mais au moins on est débarrassés de la galère que représentent les parenthèses et de la répétition des "SI" … - Une autre alternative consiste en la création d'une fonction VBA (une UDF – "User Defined Function") qui utiliserait la structure
Select Case. Si vous avez la possibilité d'utiliser les macros, songez à cette alternative car elle vous donne une grande flexibilité et n'est pas difficile à mettre en place (surtout grâce à notre tutoriel sur la structure Select Case en VBA)
Il en existe d'autres mais cela fera partie d'un autre tutoriel…
Formule Excel SI avec deux ou plusieurs conditions
Il est parfois nécessaires de vérifier plusieurs conditions en même temps pour pouvoir déterminer le résultat. De manière générale, on utilise deux types de vérifications:
- si toutes les conditions sont remplies – dans ce cas, on utilisera une formule qui combine les fonctions SI et ET
- si au moins une des conditions est remplie – ici, la fonction SI sera combinée avec la fonction OU
Ces deux combinaisons élargissent grandement le champ d'application, la flexibilité et l'efficience de la fonction SI.
Fonction SI en combinaison avec fonction ET
Si l'on veut vérifier si plusieurs conditions sont remplies en même temps, il serait naturel de tester la premier condition avec une fonction SI et si elle est remplie, tester la condition suivante avec la fonction SI suivante etc. Ce qui, par exemple, dans le cas de trois conditions, pourrait nous mener à la formule suivante:
=SI(A1="ok";SI(A2="ok";SI(A3="ok";"tout est ok";"tout n'est pas ok");"tout n'est pas ok");"tout n'est pas ok")
Il est possible de simplifier cela. Le principe est de d'abord tester avec la fonction ET si toutes les fonctions sont remplies. Ensuite utiliser une seule fonction SI pour déterminer le résultat à renvoyer. Pour rappel, la fonction ET renvoie VRAI si toutes les conditions sont remplies et FAUX si au moins une condition n'est pas remplie. Ainsi, notre formule n'utilise que deux fonctions (1x SI et 1x ET) – ce qui rend la formule finale plus lisible et plus rapide.
En pratique, cela change la formule citée plus haut en la formule suivante:
=SI(ET(A1="ok";A2="ok";A3="ok")=VRAI;"tout est ok";"tout n'est pas ok")
Dans un cas plus complexe, on peut voir par exemple ceci:
Vous pouvez voir la formule complète dans la "Barre de formule". Remarquez la fonction ET (comprenant 3 conditions) qui est surlignée en tant que condition de la fonction SI.
Fonction SI en combinaison avec fonction OU
Tout comme dans le cas précédent, le principe reste le même: vérifier grâce à la fonction OU si au moins une condition est remplie et utiliser ensuite la fonction SI pour renvoyer le résultat souhaité.
La formule SI suivante peut servir d'exemple:
=SI(OU(A1="ok";A2="ok";A3="ok")=VRAI;"au moins une valeur est ok";"rien n'est ok")
Pour rappel, la fonction OU renvoie VRAI si au moins une conditions est vraie. Elle renvoie FAUX si aucune condition n'est remplie.
À nouveau, grâce à cette combinaison, vous pouvez traiter par exemple 10 conditions différentes avec une formule composée de seulement deux fonctions…
Encore un exemple plus pratique:
Dans cet exemple, vous pouvez, à nouveau, voir que la condition de la fonction SI (ici il s'agit de la formule OU contenant trois conditions) est surlignée – c'est son résultat qui déterminera si la formule complète affichera "au moins une condition remplie" ou "aucune condition remplie".
Le cas "ultime": combinaison des fonctions SI, ET & OU dans une seule formule Excel
Les fonctions ET et OU ont un avantage considérable: il est possible de les combiner de telle sorte que cela peux couvrir un large éventail de possibilités. On reprend les principes cités plus haut pour chacune de ces fonctions et on peut l'appliquer à une situation concrète.
Prenons l'exemple suivant: Nous avons 3 conditions – A, B et C et nous voulons sélectionner tout les cas où la condition A est remplie ainsi qu'au moins une condition parmi les conditions B et C. C'est tout à fait faisable. Et pour illustrer cet exemple de manière plus concrète, on peut le transposer à une situation réelle de manière suivante:
La formule SI finale à utiliser peut donc être la suivante:
=SI(ET(A2="janvier";OU(B2>10000;C2="Oui")=VRAI)=VRAI;"entre dans le calcul";"ne rentre pas dans le calcul")
Maintenant, il suffit d'utiliser ce principe en l'adaptant à vos besoins. Comme vous pouvez le constater, la fonction SI, en combinaison avec d'autres fonctions, peut résoudre des problèmes assez complexes…
Vous pouvez trouver et tester ces trois cas dans le fichier:
Autres utilisations de la fonction SI et les fonctions apparentées
Il existe en Excel d'autres fonctions bien pratiques qui fonctionnent sur le principe de la fonction SI. En voici la liste…
- SIERREUR – une fonction très pratique grâce à laquelle vous éviterez que des erreurs tels que "
#N/A", "#DIV/0!" ou encore "#VALEUR!" d'apparaître sur l'écran. - MAX.SI & MIN.SI – nouvelles fonctions (à partir de Excel 2016) qui permettent de déterminer la valeur maximale ou minimale parmi une liste des valeurs et qui remplissent une condition particulière.
- MOYENNE.SI & SOMME.SI & NB.SI – fonctions permettant de calculer la moyenne, la somme ou le nombre de cellules qui correspondent à une condition / à un critère.
- SI.MULTIPLE et SI.CONDITIONS – fonctions qui permettent d'imbriquer plusieurs fonctions SI dans une seule fonction (disponibles à partir de Excel 2019).
Pour aller plus loin en Excel…
Si vous n'en avez pas encore assez de la fonction SI en Excel, vous pouvez consulter la page Microsoft dédiée à cette fonction. Sinon je vous propose les articles suivants…
- Liste de toutes les Fonctions Excel – liste la plus complète que vous pouvez trouver
- Fonction RECHERCHEV – tout ce que vous devriez savoir sur cette fonction incontournable
- Tutoriels sur les fonctions dérivées de SI : SOMME.SI, SOMME.SI.ENS, NB.SI et NB.SI.ENS, SI.MULTIPLE et SI.CONDITIONS
- Tout sur la nouvelle fonction phare d'Excel: RECHERCHEX
- Maxi tutoriel pour tout savoir sur le Tableau croisé dynamique Excel (TCD)
- Pour un travail plus efficace en Excel, voici une liste des raccourcis clavier utiles
- ou vous pouvez tout simplement explorer la section Excel du site Excel-Malin.com
![REMPLACER texte dans Excel [TUTORIEL]](https://cdn-0.excel-malin.com/wp-content/uploads/2024/02/REMPLACER-texte-dans-Excel-TUTORIEL.jpg)
59 commentaires sur “Fonction SI EXCEL: maîtrisez les Conditions dans Excel!”
Wow! Très bon tuto. Merci
Merci, c'est le tutoriel le plus complet que j'ai trouvé sur internet sur la fonction SI en Excel!
Bonne continuation…
J-L
très riche en infos !
Merci pour l'effort
Content de savoir que cela aide…
Bàv, Martin
Bonjour ; je veux bien que l'imbrication "SI et "OU" fonctionne, mais à condition que le seul mot (par exemple "ok") soit écrit dans la cellule.
MAIS, s'il est écrit dans une chaîne de caractères dans la cellule à ausculter, ça ne marche pas.
Pourrais-je avoir une solution, svp ? Cela fait 3 jours que je suis dessus, et là, je craque un peu.
Merci
Ma formule : si "restaurant" ou "hôtel" ou "camping" se trouve dans la cellule B5, la somme C5+E5 est écrite dans la cellule P5.
Re-merci
Bonjour,
ce n'est pas une question de nombre de mots mais de l'exactitude du contenu. Les fonctions
ETetOUcomparent le terme recherché avec le contenu complet et exact de la cellule. Donc si vous cherchez "restaurant A" et la cellule contient "restaurant A", cela va fonctionner.Pour résoudre votre problème, passez par la fonction
TROUVE– elle vérifie si une chaine de caractères en contient une autre. Le tutoriel est ici: https://excel-malin.com/tutoriels/excel-fonctions/trouve-et-cherche/Donc dans votre cas, cela devrait donner ceci:
=SI(OU(SIERREUR(TROUVE("hôtel";B5);0)>0;SIERREUR(TROUVE("restaurant";B5);0)>0;SIERREUR(TROUVE("camping";B5);0)>0)=VRAI;C5+E5;"")Cela marche pour vous? Je l'ai traduite de mémoire de l'anglais qui fonctionne:
=IF(OR(IFERROR(FIND("hôtel";B5);0)>0;IFERROR(FIND("restaurant";B5);0)>0;IFERROR(FIND("camping";B5);0)>0)=TRUE;C5+E5;"")Donc j'espère que je n'ai pas fait une faute de frappe quelque part…Bàv, Martin
Bonjour ; je m'excuse pour la réponse tardive, j'avais perdu le site.
Ca fonctionne bien, merci beaucoup
Pas de soucis…
Tant mieux que cela fonctionne. Martin
Salut!
J'effectue un grand livre des comptes sur excel
Le problème est que je veux obtenir une formule qui me facilitera la tâche:
"que la différence entre le montant débit et le montant crédit soit inscrit dans le solde débiteur seulement si le montant débit est supérieur au montant crédit "
Bonjour,
Merci pour ces précieux conseils !
Je ne parviens pas à trouver la formule me permettant de résoudre ce calcul concernant les commissions accordées aux vendeurs:
2% sur le chiffre d'affaires total + 5% sur la part du chiffre d'affaires supérieure à 25 000€.
Par exemple : Un vendeur réalise un chiffre d'affaires de 30 000 $. Sa commission s'élèvera à : 30 000 x
2 % + (30 000 – 25 000) x 5 % = 850€. Si le chiffre d'affaires est inférieur à 25 000 € le vendeur n'a
droit qu'à une commission de 2 % sur le chiffre réalisé.
Je pense utiliser une formule imbriquée mais ne parviens pas à l'organiser pour obtenir un résultat correct.
D'avance, merci pour votre aide !
Bonjour Nadège.
Cette formule fera l'affaire:
=SI(A1>25000;(A1-25000)*0,05+(A1*0,02);A1*0,02)En supposant que le montant est dans la cellule
A1.Bien à vous, Martin
Merci beaucoup ! Bonne journée à vous
C'est grâce à votre tuto que j'ai trouvé la solution à mon problème
Merci beaucoup !
Content de le lire!
Cordialement, Martin
Bonjour,
j'ai un tableau Excel 2010 avec les dates d'entretien d'équipement, et j'aimerais me créer un tableau afin de savoir combien j'aurai d,appareil pour un entretien en 2019, en 2020 ou en 2021 (je n'ai pas envie de faire un tri car certaines cellules sont jumelées).
je crois que je peux le faire avec la formule SI, mais je n'arrive pas à trouver..
Bonsoir,
Je n'ai jamais utilisé cette fonction 🙁
Je dois calculer le prix vente conseillé en O2
P.A en M2
Coef. qui est de 1.8 en N2
Formule indiquée dans cellule N2 =SI(M20;O2/M2;"")
Et là j'ai besoin d'aide, je ne sais pas ce que je dois faire.
Merci par avance
Bonjour Martin
Merci pour ce tuto bien détaillé
Je rate cependant une notion car je n’arrive pas à finaliser ma formule, Il me faut en fonction des celulles N2 P2 et R2 calculer le nombre de formations selon qu’elles soient vides ou non.
Si la cellule N2 est non vide alors 1 sinon 0 donc =SI(N2″";1;0) ça j’y arrive c’est la 1 ére formation
Là ou je n’y arrive plus c’est quand je dois imbriquer les formules
=SI(ET(N2″");1;0);SI(ET(p2″");2;1);SI(ET(r2″";3;2))
Si N2 est non vide alors il s’agit de la première formation donc 1 si elle est vide pas de formation donc rien
Si P2 est non vide il s’agit de la seconde formation à condition que N2 soit non vide aussi si N2 est vide dans ce cas enP2 c’est la première formation
Si R2 est non vide il s’agit de la troisième formation à condition que P2 et N2 soit non vide si elles sont vide alors c’est la 1ére formation
En outre je dois insérer cette formule dans l’en-tête de tableau
TPBCM (2) – du 11/05/2020 au 30/05/2020 (15) jours.
1er chiffre ( ) cest le nombre de formations 1ére 2nde ou 3éme formation que je cherche ci-dessus
Je te remercie d’avance de l’aide que tu pourrais m’apporter
Cdlt
Bonjour Nine,
pour la formule, ceci devrait faire l'affaire:
=SI(ET(N2<>"";P2="";R2="")=VRAI;1;SI(ET(N2<>"";P2<>"";R2="")=VRAI;2;SI(ET(N2<>"";P2<>"";R2<>"")=VRAI;3;SI(ET(N2="";P2<>"";R2="")=VRAI;1;SI(ET(N2="";P2="";R2<>"")=VRAI;1;0)))))et pour l'entête:
="TPBCM (" & SI(ET(N2<>"";P2="";R2="")=VRAI;1;SI(ET(N2<>"";P2<>"";R2="")=VRAI;2;SI(ET(N2<>"";P2<>"";R2<>"")=VRAI;3;SI(ET(N2="";P2<>"";R2="")=VRAI;1;SI(ET(N2="";P2="";R2<>"")=VRAI;1;0))))) & ") – du 11/05/2020 au 30/05/2020 (15) jours"où il faut après adapter le texte / les dates selon vos besoins.
Cordialement, Martin
Bonjour Martin
Merci bien pour ces formules.
Par contre je n'arrive pas à obtenir mes numérotations?
année filière niveau secteur classes sections prof principal téléphone mail pe du pe au p1 du p1 au p2 du p2 au nbr form pe nbr jours p1 nbr jours p2 nbr jours rang pe rang p1 rang p2
2020 tertiaire Post BAC BTS TRA & LOG BTS 1BTSGT M. B 22/06/2020 18/07/2020 02/11/2020 11/12/2020 2 0 20 30 1 2
2020 tertiaire Post BAC BTS TRA & LOG BTS 2BTST Mme D 09/03/2020 13/03/2020 1 0 5 0 1
2020 tertiaire BAC PRO COMMERCE/VENTE première 1BPC Mme L 24/02/2020 01/03/2020 22/06/2020 18/07/2020 02/11/2020 09/11/2020 3 5 20 6 1 2 3
mon but est que dans les autres tableaux de ne modifier dans l'en-tête que le numéro de ligne de référence dans le tableau
ne réussissant pas à calculer j'ai créer des colonnes mais seules M N O P Q R sont les bases de tout calcul
quand je modifie les dates dans le tableau il n'affiche plus le format date 00/00/2020 dans l'en-tête ?
en ligne 2
1BTSGT (1) du 22/06/2020 au 18/07/2020 (20 jours)
en-tête ici cest la 1ére formation c'est bien (1) selon les dates aucune celulle vide
1BTSGT (1) du 02/11/2020 au 11/12/2020 (30 jours)
en-tête ici cest la 2éme formation je voudrais (2) selon les dates aucune celulle vide
en ligne 3
2BTST (1) du 09/03/2020 au 43903 (5 jours)
en-tête ici cest la 1ére et la seule formation je voudrais (1) selon les dates et les celules vides en MNQR
en plus il ne m'affiche plus le nombre de jours
en ligne 4
1BPC (3) du 24/02/2020 au 43891 (5 jours)
en-tête ici cest la 1ére formationM je voudrais (1) selon les dates aucune celulle vide
colonne M & N
1BPC (3) du 22/06/2020 au 18/07/2020 (20 jours)
en-tête ici cest la 2éme formation je voudrais (2) selon les dates aucune celulle vide
colonne O & P
1BPC (3) du 02/11/2020 au 44144 (6 jours)
en-tête ici cest la 3éme formation c'est bien(3) selon les dates aucune celulle vide
colonne M & N
J'ai copier ces informations depuis excel , il faut les remettre dans un classeur pour visualiser comme il faut.
Merci de m'apporter votre aide précieuse dés que possible.
en ligne 2
='liste pp'!$F$2&" (" & SI(ET('liste pp'!$N$2″";'liste pp'!$P$2="";'liste pp'!$R$2="")=VRAI;1;SI(ET('liste pp'!$N$2″";'liste pp'!$P$2″";'liste pp'!$R$2="")=VRAI;2;SI(ET('liste pp'!$N$2″";'liste pp'!$P$2″";'liste pp'!$R$2″")=VRAI;2;SI(ET('liste pp'!$N$2="";'liste pp'!$P$2″";'liste pp'!$R$2="")=VRAI;1;SI(ET('liste pp'!$N$2="";'liste pp'!$P$2="";'liste pp'!$R$2″")=VRAI;0;1))))) & ") "&"du "&'liste pp'!$O$2&" au "&'liste pp'!$P$2&" ("&'liste pp'!$U$2&" jours"&")"
en-tête ici cest la 1ére formation c'est bien (1) selon les dates aucune celulle vide
='liste pp'!$F$2&" (" & SI(ET('liste pp'!$N$2″";'liste pp'!$P$2="";'liste pp'!$R$2="")=VRAI;1;SI(ET('liste pp'!$N$2″";'liste pp'!$P$2″";'liste pp'!$R$2="")=VRAI;3;SI(ET('liste pp'!$N$2″";'liste pp'!$P$2″";'liste pp'!$R$2″")=VRAI;3;SI(ET('liste pp'!$N$2="";'liste pp'!$P$2″";'liste pp'!$R$2="")=VRAI;1;SI(ET('liste pp'!$N$2="";'liste pp'!$P$2="";'liste pp'!$R$2″")=VRAI;0;1))))) & ") "&"du "&'liste pp'!$Q$2&" au "&'liste pp'!$R$2&" ("&'liste pp'!$V$2&" jours"&")"
en-tête ici cest la 2éme formation je voudrais (2) selon les dates aucune celulle vide
en ligne 3
='liste pp'!$F$3&" (" & SI(ET('liste pp'!$N$3″";'liste pp'!$P$3="";'liste pp'!$R$3="")=VRAI;1;SI(ET('liste pp'!$N$3″";'liste pp'!$P$3″";'liste pp'!$R$3="")=VRAI;3;SI(ET('liste pp'!$N$3″";'liste pp'!$P$3″";'liste pp'!$R$3″")=VRAI;3;SI(ET('liste pp'!$N$3="";'liste pp'!$P$3″";'liste pp'!$R$3="")=VRAI;1;SI(ET('liste pp'!$N$3="";'liste pp'!$P$3="";'liste pp'!$R$3″")=VRAI;0;1))))) & ") "&"du "&'liste pp'!$O$3&" au "&'liste pp'!$P$3&" ("&'liste pp'!$U$3&" jours"&")"
en-tête ici cest la 1ére et la seule formation je voudrais (1) selon les dates et les celules vides en MNQR
en plus il ne m'affiche plus le nombre de jours
en ligne 4
='liste pp'!$F$4&" (" & SI(ET('liste pp'!$N$4″";'liste pp'!$P$4="";'liste pp'!$R$4="")=VRAI;1;SI(ET('liste pp'!$N$4″";'liste pp'!$P$4″";'liste pp'!$R$4="")=VRAI;3;SI(ET('liste pp'!$N$4″";'liste pp'!$P$4″";'liste pp'!$R$4″")=VRAI;3;SI(ET('liste pp'!$N$4="";'liste pp'!$P$4″";'liste pp'!$R$4="")=VRAI;1;SI(ET('liste pp'!$N$4="";'liste pp'!$P$4="";'liste pp'!$R$4″")=VRAI;0;1))))) & ") "&"du "&'liste pp'!$M$4&" au "&'liste pp'!$N$4&" ("&'liste pp'!$T$4&" jours"&")"
en-tête ici cest la 1ére formationM je voudrais (1) selon les dates aucune celulle vide
colonne M & N
='liste pp'!$F$4&" (" & SI(ET('liste pp'!$N$4″";'liste pp'!$P$4="";'liste pp'!$R$4="")=VRAI;1;SI(ET('liste pp'!$N$4″";'liste pp'!$P$4″";'liste pp'!$R$4="")=VRAI;3;SI(ET('liste pp'!$N$4″";'liste pp'!$P$4″";'liste pp'!$R$4″")=VRAI;3;SI(ET('liste pp'!$N$4="";'liste pp'!$P$4″";'liste pp'!$R$4="")=VRAI;1;SI(ET('liste pp'!$N$4="";'liste pp'!$P$4="";'liste pp'!$R$4″")=VRAI;0;1))))) & ") "&"du "&'liste pp'!$O$4&" au "&'liste pp'!$P$4&" ("&'liste pp'!$U$4&" jours"&")"
en-tête ici cest la 2éme formation je voudrais (2) selon les dates aucune celulle vide
colonne O & P
Désolé voici les formules
='liste pp'!$F$4&" (" & SI(ET('liste pp'!$N$4″";'liste pp'!$P$4="";'liste pp'!$R$4="")=VRAI;1;SI(ET('liste pp'!$N$4″";'liste pp'!$P$4″";'liste pp'!$R$4="")=VRAI;3;SI(ET('liste pp'!$N$4″";'liste pp'!$P$4″";'liste pp'!$R$4″")=VRAI;3;SI(ET('liste pp'!$N$4="";'liste pp'!$P$4″";'liste pp'!$R$4="")=VRAI;1;SI(ET('liste pp'!$N$4="";'liste pp'!$P$4="";'liste pp'!$R$4″")=VRAI;0;1))))) & ") "&"du "&'liste pp'!$Q$4&" au "&'liste pp'!$R$4&" ("&'liste pp'!$V$4&" jours"&")"
en-tête ici cest la 3éme formation c'est bien(3) selon les dates aucune celulle vide
colonne M & N
Bonjour Martin
je reviens vers vous, avez-vous pu regarder ma formule
Cordialement
Bonjour nine, pas encore, désolé, j'ai été fort occupé.
Est-ce que vous pourriez m'envoyer le fichier excel par email svp?
Avec le formatage ici dans le commentaire, c'est pas très commode d'en refaire le tableau.
Merci
Bonjour
Si j'ai cette formule : =+((D16-C16)+(F16-E16)+(H16-G16))*2
Sachant que c'est le résultat d'un total d'heure sur un planning. Que cette formule *2 ne s'applique que le dimanche et pas les autres jours de la semaine.
Et je voudrais bien sûr que la cellule reconnaisse que c'est le dimanche pour être appliqué. Sinon ma formule s'écrit sans *2.
Et pour finir que mon planning se met à jour avec une liste déroulante donc mon dimanche n'est jamais à la même place.
Que dois-je écrire ?
je cherche un si sans sinon
Bonjour Lucas,
les deux arguments (si vrai / si faux) sont facultatifs. Vous pouvez donc tout simplement omettre la partie "si faux". Donc vous aurez
=SI(A2="tigre";"animal")comment faire avec si pour calculer (<1500m² pour 0.15€/m²
et supérieur pour 0.1€/m² sil vous plait ??????
Bonjour,
si le nombre de m2 se trouve dans la cellule A1, alors la formule sera:
=SI(A1<1500;A1*0,15;A1*0,1)Cordialement, Martin
Bonjour,
Je cherche depuis trois jours maintenant quelle formule utiliser pour résoudre mon problème.
J'ai un premier tableau qui contient ceci
Age Année Attestation Montant ARS
6 2015 OUI 371,80 €
7 2014 NON 371,80 €
8 2013 NON 371,80 €
9 2012 NON 371,80 €
10 2011 NON 371,80 €
11 2010 NON 392,31 €
12 2009 NON 392,31 €
13 2008 NON 392,31 €
14 2007 NON 392,31 €
15 2006 NON 405,90 €
16 2005 OUI 405,90 €
17 2004 OUI 405,90 €
18 2003 OUI 405,90 €
J'ai un deuxième tableau où j'aimerais que lorsque je tape l'année de naissance, il me donne le montant de l'ARS correspondant à la tranche d'âge.
J'espère avoir été claire..
Merci de votre aide précieuse.
Pour cela, il faut utiliser la fonction RECHERCHEV (voir tutoriel) ou, si vous disposez de Excel 365, la fonction RECHERCHEX (voir tutoriel).
Dans votre cas, si les données se trouvent dans les colonnes A à D, et l'année en question par exemple dans la cellule Z1, voici la formule:
=RECHERCHEV(Z1;A:D;3;FAUX)J'espère que cela va vous aider…
bonjour comment faire pour savoir quelle est la partie condition et quelle est partie argument dans une formule de fonction si imbriqué.
merci
Bonjour dans fonction si imbriqué vous pouvez me montrer la partie condition et la argument dans une formule de si imbriqué en excel
Bonjour
Je cherche une formule pour comparer des dates.
Si la date du jour est supérieur à la date de fin il faut afficher "Non actif" sauf si date réactualisée est inférieur donc "actif" et si elle est inférieure ou égale afficher "actif"
pouvez-vous m'aider svp
Bonjour Alyssa,
si la date de fin se trouve dans la cellule A2, vous pouvez utiliser cette formule:
=SI(AUJOURDHUI()>A2;"Non actif";"actif")Cordialement, Martin
Merci pour votre réponse. J'ai réussi à faire ma formule je cherche maintenant à ajouter une dernière condition.
Si la date du jour est supérieur à la date de fin mais que la date a été réactualisée est qu'elle est inférieur à la date du jour donc toujours actif.
Comment puis-je ajouter cette condition ?
merci bien
j'ai une quesion ? comment je pourrait faire exemple: si tout est rescepte c'est( filicitation) si c'et fait , mais avec le retarde (ok).
si c'est plusieur jour en retarde (change le stratege ) .
je vous remerci de m'aider.
Bonjour, j'ai crée une liste de choix dans une cellule par ex:(A1) et les choix (A,B,C,D,E,F) et j'ai une autre cellule avec également des choix ex: B1 et les choix (0;1,2,3,4) et j'aimerais dans ma 3ème cellule C1 obtenir la réponse suivante:
Si A1 est égale à A ou B ou C ou D ou F est égale à "X" sauf si B1 qui est égale à "0" et qui sera donc égale à "Vide" (pas besoin des autres choix 1/2/3/4, le "0" suffit)
Bonjour, voici la formule:
=SI(B1=0;"";SI(OU(A1="A";A1="B";A1="C";A1="D";A1="F")=VRAI;"X"))Le cas où A1 = "E" et B1 <> 0 que vous ne mentionnez pas dans votre question va donner un "vide".
J'espère que cela vous a aidé. Cordialement, Martin
Bonjour, je découvre votre site et vous faites de super Tuto très clair, Merci!
Auriez-vous une solution pour cet exemple :
A1 = Nombre xx,50
Si A1 a les décimales a xx,50 alors arrondir au 0,5 SUPerieur le plus proche
Exemple
Si A1 = 12,45 donc le résultat affiché sera 12,00
Si A1 = 13,58 donc le résultat affiché sera 14,00
Merci pour votre aide!
Bonjour Pat,
oui, la solution, j'en ai une 😉
Votre formule:
=SI(A1-TRONQUE(A1;0)>=0,5;PLAFOND.MATH(A1;0,5);PLANCHER.MATH(A1;0,5))
J'espère que cela va vous aider.
Cordialement, Martin
C'est incroyablement beau votre formule! Merci beaucoup!
Si la moyenne est supérieure ou égale à 10 alors on affiche ok ou sinon échec
Si la moyenne est comprise entre 8 et 10 mais que l'une des notes est supérieure à 12 alors on affiche ok sinon échec
Si aucune des conditions n'est remplie alors échec.
Merci de m'aider sur ce problème que je n'arrive pas à résoudre depuis 1 semaine. Please.
Bonjour Marie Noelle,
Voici la formule – vous devez adapter la plage avec des notes, j'ai utilisé la plage "A1:A10":
=SI(MOYENNE(A1:A10)>=10;"ok";SI(ET(MOYENNE(A1:A10)<10;MOYENNE(A1:A10)>=8;MAX(A1:A10)>=12)=VRAI;"ok";"échec"))J'espère que cela va vous aider.
Bien à vous, Martin
Je veux savoir:
Dans mes colonnes A et B se trouvent OUI, NON, NON, NON vis versa: je veux attribuer à chacun de critères des notes 1pt. Si c'est A=oui et B=oui je donne 1point; A=oui et B=non je donne aussi 1 point et Si A=non et B=non je donne 0
Bonjour Martin,
Je suis tombé sur votre tuto après avoir posté sur des forums, et j'avoue que cela correspond à ce que je cherchais. Par contre je m'arrache toujours les cheveux sur la formule finale. Au vu de votre topic, j'ai fait un test avec une version simplifié de ce que je veux faire où C13 est soit inférieur à 200 donc sera multiplié par 1.1 soit supérieur à 200 et sera multiplié par 1.1 : =SI(C13600;C13*1,1;"NA") mais Excel me marque VALEUR quand je valide. Je pense que j'ai loupé un truc dans la jonction des 2 formules. Par contre les deux formules en SI séparées marchent grâce à votre tuto 🙂 Mais j'ai besoin de les combiner et de pousser le truc un peu plus loin. Pour expliquer ce que je cherche à faire, j'ai un nombre Z suite à une formule toute banale de multiplication et je voudrais une formule qui dise :
• Si Z est 600 il faut la multiplier par 6.1
En vous remerciant pour votre aide.
Par avance un excellent week-end !
Bonsoir Yoann, je vous ai envoyé les explications par email. M.
Bonjour,
Si je veux que ceci fonctionne, que dois-je écrire? Je veux que dans la case D3 ça écrive court si dans la case D2 le nombre est de 0 à 49, je veux que dans la case D3 ça écrive moyen si dans la case D2 le nombre est de 50 à 99 et je veux que dans la case D3 ça écrit long si dans la case D2 le nombre est de plus grand ou égal à 100. J'ai essayé beaucoup de choses, mais rien ne fonctionne… Merci!
Bonjour Ju,
il s'agit de deux fonctions SI imbriquées.
Voici donc votre formule:
=SI(D2<50;"court";SI(D2<100;"moyen";"long"))Martin
Salut!
Pour une raison obscure, je n'arrive pas à obtenir un résultat avec la formule SI.
Ma cellule L2 a une valeur de 78.
Dans ma cellule M2, j'ai inscrit la formule suivante : =SI(L2<=0, ''Oui'' , ''Non'')
La formule reste inscrite dans la cellule.
Bonjour David,
vous voulez dire que vous voyez quelque chose comme ça?:
Si c'est le cas, c'est parce que votre cellule est à la base formatée comme "texte". Dans ce cas, quand vous inscrivez la formule dans la cellule, Excel considère cela comme du simple texte et pas comme une formule.
SOLUTION:
avant d'inscrire la formule, changez le format de la cellule en "Standard".
Si la formule est déjà dans la cellule, changez le format en "standard", ensuite cliquez dans la barre de formule et confirmez la formule avec la touche "Entrée"…
Bonjour, excellent tutoriel, je me posais une question par rapport à une formule SI. Je souhaiterais tenter de "combiner" 2 formules mais je n'arrive pas à trouver la formule dont j'ai besoin
Les 2 formules sont : =SI((F2/E2)>0;F2/E2;0%) et =SI((F2/E2)<150;F2/E2;150%) Auriez-vous une formule commune afin de pouvoir utiliser ces 2 formules et une seule seule et même ?
Merci beaucoup d'avance
En une seule et même*
S'il vous plaît !
Bonjour Thomas,
vous pouvez utiliser cette formule:
=SI((F2/E2)>150;150%;SI(F2/E2<0;0%;F2/E2))
Bien à vous, MArtin
Bonjour,
J'ai une formule à retrouver et je galère sur cet exercice.
J'ai 3 colonnes A4 Salarié, B4 Ancienneté et C4 prime
En A5 j'ai les prénoms des salariés jusqu'en A15 et le B5 j'ai le premier salarié en 2 ans, je dois calculer la prime qui sera accordée à partir de la 5ème année et elle s'élève à 30€ par année supplémentaire. Je pense utiliser la fonction Si avec plusieurs conditions mais je galère totalement quelqu'un peut il m'aider?
Bonjour Martin,
Merci pour vos précieux conseils et explications.
Juste une petit question: y a t'il moyen de modifier la couleur de police d'une cellule si la condition est remplie?
Je voudrais par exemple que si valeur de cellule A > valeur de cellule B, alors résultat cellule C = couleur de police vert
D'avance un grand merci si vous avez le temps de me répondre.
Dominique Flore (Belgique)
Bonjour Dominique,
Bien sûr, je peux vous aider avec votre question. Voici comment procéder pour changer la couleur de police d'une cellule selon une condition dans Excel. Cette méthode utilise la mise en forme conditionnelle, une fonctionnalité très utile d'Excel. Je vais l'expliquer étape par étape :
=A1>B1. Cette formule signifie que la mise en forme s'appliquera si la valeur de la cellule A est supérieure à celle de la cellule B. Assurez-vous de remplacer 'A1' et 'B1' par les références exactes de vos cellules si elles sont différentes.Maintenant, si la valeur dans la cellule A est supérieure à celle dans la cellule B, la couleur de la police dans la cellule C devrait automatiquement devenir verte.
J'espère que ces instructions vous seront utiles! Martin
Ca marche, formidable !
Merci beaucoup Martin, de prendre de votre temps pour vulgariser gracieusement Excel, et de manière ultra didactique.
C'est vraiment génial…
Dans mon tableau j'ai une colonne D avec des montants au DEBIT et dans la E des montants au CREDIT, J'aimerais faire une formule qui puisse me mettre dans la colonne B un texte DEBIT ou CEDIT si il y a un montant dans la colonne D ou E. meci de votre aide
Oui, c’est tout à fait possible.
Si vous êtes sûr qu’au moins une des deux colonnes est remplie, vous pouvez utiliser cette formule :
=SI(D2<>"";"DEBIT";"CREDIT")À placer dans la cellule B2.
S’il est possible que les deux cellules soient vides, alors utilisez ceci :
=SI(D2<>"";"DEBIT";SI(E2<>"";"CREDIT";""))Ainsi, si les cellules D e E sont vides, la B restera vide également.